Assistance Needed for Efficiently Operating Two VL53L8CX Sensors on Arduino DUE

[LelioG]

Hello,

I am reaching out regarding an issue with the library associated with the VL53L8CX sensor, specifically the function vl53l8cx_stop_ranging().

My goal is to operate multiple SATEL-VL53L8 sensors directly on an Arduino DUE without using a P-NUCLEO-53L8A1 by connecting the SATELs directly to the Arduino DUE board. The method I found involves initializing the sensors by changing their addresses according to the protocol provided by ST, starting a ranging session for one sensor with vl53l8cx_start_ranging(), collecting its data, stopping the ranging session with vl53l8cx_stop_ranging(), and then starting the ranging session on the second sensor.

This method works, but the problem is that the vl53l8cx_stop_ranging() function takes about 1 second to execute, making it impossible to achieve my goal of running the sensors at more than 20Hz if I have to call this function each time.

I would like to know if it is necessary to call this function every time I want to switch to another sensor and, if so, how I can improve its execution time.

Thank you for your assistance.

To reproduce :

My code :

/* Includes ------------------------------------------------------------------*/
#include <Arduino.h>
#include <Wire.h>
#include <vl53l8cx_class.h>


#ifdef ARDUINO_SAM_DUE
 #define DEV_I2C Wire
#else
 #define DEV_I2C Wire
#endif
#define SerialPort Serial

#define LPN_PIN_1 2
#define I2C_RST_PIN -1
#define PWREN_PIN 3
#define PWREN_PIN_2 5
#define LPN_PIN_2 4

#define NUM_SENSORS 2
uint8_t i2c_addresses[NUM_SENSORS] = {0x66, 0x68};


void print_result(VL53L8CX_ResultsData *Result, const char *sensorName);
unsigned long startTime = 0;
unsigned long endTime = 0;
bool timing = false;

// Components.
VL53L8CX sensors[NUM_SENSORS] = {
 VL53L8CX(&DEV_I2C, LPN_PIN_1, I2C_RST_PIN),
 VL53L8CX(&DEV_I2C, LPN_PIN_2, I2C_RST_PIN)
};


VL53L8CX_ResultsData results[NUM_SENSORS];
uint8_t newDataReady[NUM_SENSORS] = {0};
uint8_t statuses[NUM_SENSORS];

uint8_t res = VL53L8CX_RESOLUTION_4X4;
char report[256];
int status;
/* Setup ---------------------------------------------------------------------*/



void setup() {
 // Initialize serial communication
 SerialPort.begin(460800);
 Serial.println("Serial communication initialized");

 // Initialize I2C communication
 Wire.begin();
 Serial.println("I2C communication initialized");

 // Configure PWREN 
 configure_pwren();

 // Configure LPn pins
 configure_pins();
 delay(100);
 
 // Initialize each sensor
 for (int i = 0; i < NUM_SENSORS; i++) {
   initialize_sensor(sensors[i], get_lpn_pin(i), i2c_addresses[i], i);
 }

 // Start ranging for all sensors
 activate_sensors();
}

void configure_pins() {
 pinMode(LPN_PIN_1, OUTPUT);
 digitalWrite(LPN_PIN_1, LOW);  // Set LPn pin to Low for sensor 1
 Serial.println("LPN_PIN_1 configured and set LOW");

 pinMode(LPN_PIN_2, OUTPUT);
 digitalWrite(LPN_PIN_2, LOW);  // Set LPn pin to Low for sensor 2
 Serial.println("LPN_PIN_2 configured and set LOW");
}

void configure_pwren() {

if (PWREN_PIN >= 0) {
   pinMode(PWREN_PIN, OUTPUT);
   digitalWrite(PWREN_PIN, HIGH);
   delay(10);
   Serial.println("PWREN_PIN configured and set HIGH");
 }

 if (PWREN_PIN_2 >= 0) {
   pinMode(PWREN_PIN_2, OUTPUT);
   digitalWrite(PWREN_PIN_2, HIGH);
   delay(10);
   Serial.println("PWREN_PIN_2 configured and set HIGH");
 }


}





int get_lpn_pin(int sensor_number) {
 switch (sensor_number) {
   case 0:
     return LPN_PIN_1;
   case 1:
     return LPN_PIN_2;
   default:
     return -1;  // Invalid sensor number
 }
}

void initialize_sensor(VL53L8CX &sensor, int lp_pin, uint8_t new_i2c_address, int sensor_number) {
 digitalWrite(lp_pin, HIGH);  // Activate sensor
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" activated");

 sensor.begin();
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" begin called");

 sensor.init_sensor();
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" initialized");

 uint8_t status = sensor.vl53l8cx_set_i2c_address(new_i2c_address);
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.print(" I2C address change status: ");
 Serial.println(status);

 digitalWrite(lp_pin, LOW);   // Deactivate sensor
 delay(1000);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" deactivated");
}

void activate_sensors() {
 digitalWrite(LPN_PIN_1, HIGH);  // Activate sensor 1
 digitalWrite(LPN_PIN_2, HIGH);  // Activate sensor 2
 Serial.println("Sensors activated with new addresses");
}


void loop() {
 // Check data ready for each sensor
 delay(10);
 for (int i = 0; i < NUM_SENSORS; ++i) {
   sensors[i].vl53l8cx_start_ranging();
   do {
     
     statuses[i] = sensors[i].vl53l8cx_check_data_ready(&newDataReady[i]);
     
     if (statuses[i] != 0) {
       Serial.print("Error checking data ready for Sensor ");
       Serial.print(i + 1);
       Serial.print(": ");
       Serial.println(statuses[i]);
       delay(10);  // Add delay to prevent continuous looping on error
     }
   } while (!newDataReady[i]);
   sensors[i].vl53l8cx_stop_ranging();
 }
 

 // Read ranging data for each sensor
 for (int i = 0; i < NUM_SENSORS; ++i) {
   sensors[i].vl53l8cx_start_ranging();
   if (newDataReady[i]) {
     statuses[i] = sensors[i].vl53l8cx_get_ranging_data(&results[i]);
     
     
     if (statuses[i] == 0) {
       char sensorName[10]; // TO store the name of the sensor
       sprintf(sensorName, "Sensor %d", i + 1); // Format sensor name
       
       print_result(&results[i], sensorName);
     } else {
       Serial.print("Error getting ranging data for Sensor ");
       Serial.print(i + 1);
       Serial.print(": ");
       Serial.println(statuses[i]);
     }
   }
   sensors[i].vl53l8cx_stop_ranging();
   
 }


}



void print_result(VL53L8CX_ResultsData *Result, const char *sensorName) {
 Serial.print(sensorName);
 Serial.print(": ");

 //Print distance for each detected zone
 for (int i = 0; i < res; i++) {
   if (Result->nb_target_detected[i] > 0) {
     Serial.print("Zone ");
     Serial.print(i);
     Serial.print(": ");
     Serial.print(Result->distance_mm[i]);
     Serial.print(" mm, ");
   }
 }
 Serial.println();
}

Desktop :

OS: Windows 11 / Ubuntu 22.04
Arduino IDE version: 2.3.3
STM32 core version: N/A
Library version: 1.0.4
Tools menu settings if not the default: N/A
Upload method: Default serial

Hardware :

Board Name: Arduino Due ( Atmel ATSAM3X8EAU ARM )
Hardware Revision: N/A
Extra hardware used if any: No

[cparata]

Hello @LelioG ,
start_ranging and stop_ranging are time consuming and you do not need to call the stop_ranging any time if you want to go in continuous mode. So you can try this sketch:

/* Includes ------------------------------------------------------------------*/
#include <Arduino.h>
#include <Wire.h>
#include <vl53l8cx_class.h>


#ifdef ARDUINO_SAM_DUE
 #define DEV_I2C Wire
#else
 #define DEV_I2C Wire
#endif
#define SerialPort Serial

#define LPN_PIN_1 2
#define I2C_RST_PIN -1
#define PWREN_PIN 3
#define PWREN_PIN_2 5
#define LPN_PIN_2 4

#define NUM_SENSORS 2
uint8_t i2c_addresses[NUM_SENSORS] = {0x66, 0x68};


void print_result(VL53L8CX_ResultsData *Result, const char *sensorName);
unsigned long startTime = 0;
unsigned long endTime = 0;
bool timing = false;

// Components.
VL53L8CX sensors[NUM_SENSORS] = {
 VL53L8CX(&DEV_I2C, LPN_PIN_1, I2C_RST_PIN),
 VL53L8CX(&DEV_I2C, LPN_PIN_2, I2C_RST_PIN)
};


VL53L8CX_ResultsData results[NUM_SENSORS];
uint8_t newDataReady[NUM_SENSORS] = {0};
uint8_t statuses[NUM_SENSORS];

uint8_t res = VL53L8CX_RESOLUTION_4X4;
char report[256];
int status;
/* Setup ---------------------------------------------------------------------*/



void setup() {
 // Initialize serial communication
 SerialPort.begin(460800);
 Serial.println("Serial communication initialized");

 // Initialize I2C communication
 Wire.begin();
 Serial.println("I2C communication initialized");

 // Configure PWREN 
 configure_pwren();

 // Configure LPn pins
 configure_pins();
 delay(100);
 
 // Initialize each sensor
 for (int i = 0; i < NUM_SENSORS; i++) {
   initialize_sensor(sensors[i], get_lpn_pin(i), i2c_addresses[i], i);
 }

 // Start ranging for all sensors
 activate_sensors();

 for (int i = 0; i < NUM_SENSORS; ++i) {
   sensors[i].vl53l8cx_start_ranging();
 }
}

void configure_pins() {
 pinMode(LPN_PIN_1, OUTPUT);
 digitalWrite(LPN_PIN_1, LOW);  // Set LPn pin to Low for sensor 1
 Serial.println("LPN_PIN_1 configured and set LOW");

 pinMode(LPN_PIN_2, OUTPUT);
 digitalWrite(LPN_PIN_2, LOW);  // Set LPn pin to Low for sensor 2
 Serial.println("LPN_PIN_2 configured and set LOW");
}

void configure_pwren() {

if (PWREN_PIN >= 0) {
   pinMode(PWREN_PIN, OUTPUT);
   digitalWrite(PWREN_PIN, HIGH);
   delay(10);
   Serial.println("PWREN_PIN configured and set HIGH");
 }

 if (PWREN_PIN_2 >= 0) {
   pinMode(PWREN_PIN_2, OUTPUT);
   digitalWrite(PWREN_PIN_2, HIGH);
   delay(10);
   Serial.println("PWREN_PIN_2 configured and set HIGH");
 }


}





int get_lpn_pin(int sensor_number) {
 switch (sensor_number) {
   case 0:
     return LPN_PIN_1;
   case 1:
     return LPN_PIN_2;
   default:
     return -1;  // Invalid sensor number
 }
}

void initialize_sensor(VL53L8CX &sensor, int lp_pin, uint8_t new_i2c_address, int sensor_number) {
 digitalWrite(lp_pin, HIGH);  // Activate sensor
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" activated");

 sensor.begin();
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" begin called");

 sensor.init_sensor();
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" initialized");

 uint8_t status = sensor.vl53l8cx_set_i2c_address(new_i2c_address);
 delay(100);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.print(" I2C address change status: ");
 Serial.println(status);

 digitalWrite(lp_pin, LOW);   // Deactivate sensor
 delay(1000);
 Serial.print("Sensor ");
 Serial.print(sensor_number);
 Serial.println(" deactivated");
}

void activate_sensors() {
 digitalWrite(LPN_PIN_1, HIGH);  // Activate sensor 1
 digitalWrite(LPN_PIN_2, HIGH);  // Activate sensor 2
 Serial.println("Sensors activated with new addresses");
}


void loop() {
 // Check data ready for each sensor
 for (int i = 0; i < NUM_SENSORS; ++i) {
   do {
     
     statuses[i] = sensors[i].vl53l8cx_check_data_ready(&newDataReady[i]);
     
     if (statuses[i] != 0) {
       Serial.print("Error checking data ready for Sensor ");
       Serial.print(i + 1);
       Serial.print(": ");
       Serial.println(statuses[i]);
     }
   } while (!newDataReady[i]);

   if ((!statuses[i]) && (newDataReady[i] != 0)) {
    // Read measured distance. RangeStatus = 5 and 9 means valid data
    statuses[i] = sensors[i].vl53l8cx_get_ranging_data(&results[i]);

    if (statuses[i] == 0) {
       char sensorName[10]; // TO store the name of the sensor
       sprintf(sensorName, "Sensor %d", i + 1); // Format sensor name
       
       print_result(&results[i], sensorName);
     } else {
       Serial.print("Error getting ranging data for Sensor ");
       Serial.print(i + 1);
       Serial.print(": ");
       Serial.println(statuses[i]);
     }
  }
 }
}



void print_result(VL53L8CX_ResultsData *Result, const char *sensorName) {
 Serial.print(sensorName);
 Serial.print(": ");

 //Print distance for each detected zone
 for (int i = 0; i < res; i++) {
   if (Result->nb_target_detected[i] > 0) {
     Serial.print("Zone ");
     Serial.print(i);
     Serial.print(": ");
     Serial.print(Result->distance_mm[i]);
     Serial.print(" mm, ");
   }
 }
 Serial.println();
} 

Please, give a look at this code to see how to use multiple sensors in I2C.
Best Regards,
Carlo

[cparata]

Hi @LelioG ,
you could try to set the I2C speed at 400KHz to speed up the write/read operations from the device registers. You can just call after the Wire.begin() the following API:

Wire.setClock(400000);

Then, consider that the "print" takes some time to be executed. If you want to reach the maximum frequency, you should remove them from the code.
Best Regards,
Carlo